Hinweis
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, sich anzumelden oder das Verzeichnis zu wechseln.
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, das Verzeichnis zu wechseln.
Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Lernprogramm für Log Analytics. Informationen zur REST-API finden Sie unter "Abfrage".
Erweiterte Messaging-Vorgänge
Gibt alle unterschiedlichen Kombinationen von Advanced Messaging-Vorgangs- und Versionspaaren zurück.
ACSAdvancedMessagingOperations
| distinct OperationName, OperationVersion
| limit 100
Dauer des erweiterten Messaging-Vorgangs in Prozent
Berechnet das 90., 95. und 99. Perzentil der Ausführungsdauer in Millisekunden für jede Chat-Operation. Es kann so angepasst werden, dass es für einen einzelnen Vorgang oder für andere Perzentile ausgeführt wird.
ACSAdvancedMessagingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100
Fortschrittliche Nachrichtenübermittlung: Top 5 IP-Adressen pro Vorgang
Rufen Sie für jeden Advanced Messaging-Vorgang die fünf IP-Adressen ab, die diesen Vorgang am häufigsten aufgerufen haben.
ACSAdvancedMessagingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100
Vorgangsfehler bei der erweiterten Nachrichtenübermittlung
Listet jeden Advanced Messaging-Fehler auf, der nach Aktualität sortiert ist.
ACSAdvancedMessagingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100
Ergebnisanzahl des erweiterten Nachrichtenübermittlungsvorgangs
Zählen Sie für jeden Advanced Messaging-Vorgang die Typen der zurückgegebenen Ergebnisse.
ACSAdvancedMessagingOperations
| summarize Count = count() by OperationName, OperationVersion, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType
| order by OperationName asc, Count desc
| limit 100
Erweiterte Messaging-Kanalaktivität
Zusammenfassung der Nachrichtenaktivität pro Kanal für die letzten 24 Stunden.
ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize count() by ChannelId, MessageType
| order by ChannelId asc
Nachrichtenstatusanzahl bei der erweiterten Nachrichtenübermittlung
Anzahl der Status der Nachrichten in den letzten 24 Stunden.
ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize Count = count() by MessageType, MessageStatus
| order by MessageType asc, Count desc