Tutorial: unir dados de várias tabelas

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A junção de dados de várias tabelas permite analisar dados entre fontes e criar relações entre pontos de dados. Na KQL (Linguagem de Consulta Kusto), use os operadores de junção e pesquisa para combinar dados entre tabelas.

Neste tutorial, você aprenderá como:

Pré-requisitos

Execute as consultas em um ambiente de consulta que tenha acesso aos dados de exemplo. Use um dos seguintes:

Usar o operador de junção

O banco de dados Exemplos tem duas tabelas de eventos de tempestade relacionadas: StormEvents e PopulationData. Nesta seção, você os une para analisar dados que não são possíveis apenas com uma tabela.

Entender os dados

Use o operador take para ver quais dados cada tabela contém.

StormEvents 
| take 5

A tabela a seguir mostra apenas seis das 22 colunas retornadas.

PopulationData 
| take 5

Saída

Ambas as tabelas têm uma State coluna. StormEvents tem muito mais colunas e PopulationData tem uma outra coluna com a população do estado.

Junte-se às tabelas

Junte PopulationData com StormEvents em State para calcular os danos totais à propriedade per capita em cada estado.

StormEvents
| summarize PropertyDamage = sum(DamageProperty) by State
| join kind=innerunique PopulationData on State
| project State, PropertyDamagePerCapita = PropertyDamage / Population
| sort by PropertyDamagePerCapita

Adicione | render columnchart à consulta para visualizar o resultado.

Se as colunas tiverem nomes diferentes (por exemplo, StormEvents tem State e PopulationData tem StateName), especifique a junção como:

StormEvents
| join kind=innerunique PopulationData on $left.State == $right.StateName  

$left refere-se à tabela esquerda (externa) na junção: StormEvents. $right refere-se à tabela direita (interna): PopulationData.

Usar o operador de pesquisa

O operador de pesquisa otimiza consultas que enriquecem uma tabela de fatos com dados de uma tabela de dimensão. Ele estende a tabela de fatos com valores da tabela de dimensão. Por padrão, o sistema pressupõe que a tabela esquerda é a tabela de fatos maior e a tabela direita é a tabela de dimensões menor. Esse padrão é o oposto da pressuposição do operador join.

O cluster de ajuda inclui um banco de dados nomeado ContosoSales com dados de vendas. A consulta a seguir usa lookup para mesclar as tabelas SalesFact e Products para retornar o total de vendas por categoria de produto.

SalesFact
| lookup Products on ProductKey
| summarize TotalSales = count() by ProductCategoryName
| order by TotalSales desc

Saída

Unir tabelas geradas por consulta

Unir resultados da mesma tabela.

Suponha que você queira uma lista de estados que tenham eventos de raios e avalanches. Use o operador de junção para mesclar linhas de duas consultas que retornam estados distintos para cada tipo de evento na State coluna.

StormEvents
| where EventType == "Lightning"
| distinct State
| join kind=inner (
    StormEvents 
    | where EventType == "Avalanche"
    | distinct State
    )
    on State
| project State

Saída

Conteúdo relacionado

• Saiba mais sobre diferentes tipos de operador de junção.
• Execute consultas entre bancos de dados e entre clusters.
• Siga o tutorial Criar visualizações geoespaciais .