Compartilhar via

Método Document.SaveAs2 (Word)

Salva o documento especificado com um novo nome ou formato. Alguns argumentos para esse método correspondem às opções da caixa de diálogo Salvar como (guia Arquivo).

Sintaxe

expression. SaveAs2( _FileName_ , _FileFormat_ , _LockComments_ , _Password_ , _AddToRecentFiles_ , _WritePassword_ , _ReadOnlyRecommended_ , _EmbedTrueTypeFonts_ , _SaveNativePictureFormat_ , _SaveFormsData_ , _SaveAsAOCELetter_ , _Encoding_ , _InsertLineBreaks_ , _AllowSubstitutions_ , _LineEnding_ , _AddBiDiMarks_ , _CompatibilityMode_ )

expressão Uma expressão que devolve um objeto Documento .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
FileName Opcional Variant O nome do documento. O padrão é a pasta atual e o nome de arquivo. Se o documento nunca foi salvo, o nome padrão será usado (por exemplo, Doc1.doc). Se já existir um documento com o FileName especificado, o documento será substituído sem que o usuário seja alertado antes.
FileFormat Opcional Variant O formato no qual o documento é salvo. Pode ser qualquer constante WdSaveFormat . Para guardar um documento noutro formato, especifique o valor adequado para a propriedade SaveFormat do objeto FileConverter .
LockComments Opcional Variant True para bloquear o documento para comentários. O padrão é False.
Password Opcional Variant Uma cadeia de caracteres de senha para abrir o documento. (Consulte os Comentários abaixo.)
AddToRecentFiles Opcional Variant True para adicionar o documento à lista de arquivos recentemente usados no menu Arquivo. O padrão é True.
WritePassword Opcional Variant Uma cadeia de caracteres de senha para salvar as alterações no documento. (Consulte os Comentários abaixo.)
ReadOnlyRecommended Opcional Variant True para que o Microsoft Word sugira o status somente leitura sempre que um documento for aberto. O padrão é False.
EmbedTrueTypeFonts Opcional Variant True para salvar fontes TrueType com o documento. Se omitido, o argumento EmbedTrueTypeFonts assume o valor da propriedade EmbedTrueTypeFonts .
SaveNativePictureFormat Opcional Variant Se foram importados elementos gráficos de outra plataforma (por exemplo, do Macintosh), True para salvar somente a versão para Microsoft Windows dos elementos gráficos importados.
SaveFormsData Opcional Variant True para salvar os dados inseridos por um usuário em um formulário como um registro.
SaveAsAOCELetter Opcional Variant Se um documento tiver um mensageiro anexado, True para salvar o documento como uma carta AOCE (o mensageiro é salvo).
Encoding Optional Variant A página de código ou o conjunto de caracteres a ser usado no caso de documentos salvos como arquivos de texto codificados. O padrão é a página de código do sistema. Não pode utilizar todas as constantes msoEncoding com este parâmetro.
InsertLineBreaks Opcional Variant Se o documento foi salvo como um arquivo de texto, True para inserir quebras de linha no final de cada linha de texto.
AllowSubstitutions Opcional Variant Se o documento foi salvo como um arquivo de texto, True permite ao Word substituir alguns símbolos por texto que pareça semelhante. Por exemplo, exibindo o símbolo de direito autoral como (c). O padrão é False.
Endeamento de Linhas Opcional Variant O modo como o Word assinala as quebras de linha e parágrafo em documentos salvos como arquivos de texto. Pode ser uma das seguintes constantes WdLineEndingType : wdCRLF (predefinição) ou wdCROnly.
AddBiDiMarks Opcional Variant True adiciona caracteres de controle ao arquivo de saída para preservar o layout bidirecional do texto no documento original.
CompatibilityMode Opcional Variant O modo de compatibilidade que Word utiliza ao abrir o documento. Constante WdCompatibilityMode .
Importante
Por predefinição, se não for especificado nenhum valor para este parâmetro, Word introduz um valor de 0, que especifica que o modo de compatibilidade atual do documento deve ser mantido.

Valor de retorno

Nada

Exemplo

O exemplo de código a seguir salva o documento ativo como Test.rtf no formato rich text (RTF).

Sub SaveAsRTF() 
    ActiveDocument.SaveAs2 FileName:="Text.rtf", _ 
        FileFormat:=wdFormatRTF 
End Sub

O exemplo de código a seguir salva o documento ativo no formato de arquivo texto, com a extensão ".txt".

Sub SaveAsTextFile() 
    Dim strDocName As String 
    Dim intPos As Integer 
 
    ' Find position of extension in file name 
    strDocName = ActiveDocument.Name 
    intPos = InStrRev(strDocName, ".") 
 
    If intPos = 0 Then 
 
        ' If the document has not yet been saved 
        ' Ask the user to provide a file name 
        strDocName = InputBox("Please enter the name " & _ 
            "of your document.") 
    Else 
 
        ' Strip off extension and add ".txt" extension 
        strDocName = Left(strDocName, intPos - 1) 
        strDocName = strDocName & ".txt" 
    End If 
 
    ' Save file with new extension 
    ActiveDocument.SaveAs2 FileName:=strDocName, _ 
        FileFormat:=wdFormatText 
End Sub

O seguinte exemplo de código percorre todos os conversores instalados e, se encontrar o conversor do WordPerfect 6.0, guarda o documento ativo com o conversor.

Sub SaveWithConverter() 
 
    Dim cnvWrdPrf As FileConverter 
 
    ' Look for WordPerfect file converter 
    ' And save document using the converter 
    ' For the FileFormat converter value 
    For Each cnvWrdPrf In Application.FileConverters 
        If cnvWrdPrf.ClassName = "WrdPrfctWin" Then 
            ActiveDocument.SaveAs2 FileName:="MyWP.doc", _ 
                FileFormat:=cnvWrdPrf.SaveFormat 
        End If 
    Next cnvWrdPrf 
 
End Sub

O exemplo de código a seguir mostra um procedimento que salva um documento com uma senha.

Sub SaveWithPassword(docCurrent As Document, strPWD As String) 
    With docCurrent 
        .SaveAs2 WritePassword:=strPWD 
    End With 
End Sub

Confira também

Objeto Document

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on