Método Selection.NextRevision (Word)

Localiza e retorna a próxima alteração controlada como um objeto Revision.

Sintaxe

expression. NextRevision( _Wrap_ )

expressão Obrigatório. Uma variável que representa um objeto Selection.

Parâmetros

Valor de retorno

Revision

Comentários

O texto alterado se torna a seleção atual. Use as propriedades do objeto Revision resultante para ver qual tipo de alteração ele é, quem a fez e assim por diante. Use os métodos do objeto Revision para aceitar ou rejeitar a alteração.

Se não houver alterações controladas para serem encontradas, a seleção atual continua inalterada.

Exemplo

Este exemplo rejeita a próxima alteração controlada encontrada depois do quinto parágrafo no documento ativo. A revTempvariável está definida como Nada se não for encontrada uma alteração.

Dim rngTemp as Range 
Dim revTemp as Revision 
 
If ActiveDocument.Paragraphs.Count >= 5 Then 
 Set rngTemp = ActiveDocument.Paragraphs(5).Range 
 rngTemp.Select 
 Set revTemp = Selection.NextRevision(Wrap:=False) 
 If Not (revTemp Is Nothing) Then revTemp.Reject 
End If

Este exemplo aceita a próxima alteração controlada encontrada se o tipo de mudança for texto inserido.

Dim revTemp as Revision 
 
Set revTemp = Selection.NextRevision(Wrap:=True) 
If Not (revTemp Is Nothing) Then 
 If revTemp.Type = wdRevisionInsert Then revTemp.Accept 
End If

Este exemplo encontra a próxima revisão após a seleção atual feita pelo autor do documento.

Dim revTemp as Revision 
Dim strAuthor as String 
 
strAuthor = ActiveDocument.BuiltInDocumentProperties(wdPropertyAuthor) 
 
Do While True 
 Set revTemp = Selection.NextRevision(Wrap:=False) 
 If Not (revTemp Is Nothing) Then 
 If revTemp.Author = strAuthor Then 
 MsgBox Prompt:="Another revision by " & strAuthor & "!" 
 Exit Do 
 End If 
 Else 
 MsgBox Prompt:="No more revisions!" 
 Exit Do 
 End If 
Loop

Confira também

Objeto Selection

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.