Aplicar um plano de consulta fixo a um guia de plano

Você pode aplicar um plano de consulta fixo a um guia de plano do tipo OBJECT ou SQL. Guias de plano que aplicam um plano de consulta fixo são úteis quando você sabe sobre um plano de execução existente que tem um desempenho melhor do que aquele selecionado pelo otimizador para uma consulta específica.

O exemplo a seguir cria um guia de plano para uma instrução SQL ad hoc simples. O plano de consulta desejado para essa instrução é fornecido no guia de plano especificando o plano de exibição XML para a consulta diretamente no @hints parâmetro. O exemplo primeiro executa a instrução SQL para gerar um plano no cache do plano. Para os fins deste exemplo, supõe-se que o plano gerado seja o plano desejado e não é necessário nenhum ajuste adicional na consulta. O plano de exibição XML para a consulta é obtido consultando as exibições de gerenciamento dinâmico sys.dm_exec_query_stats, sys.dm_exec_sql_text e sys.dm_exec_text_query_plan, e é atribuído à variável @xml_showplan. A variável @xml_showplan é então passada para a instrução sp_create_plan_guide no parâmetro @hints. Ou você pode criar um guia de plano a partir de um plano de consulta no cache de planos usando o procedimento armazenado sp_create_plan_guide_from_handle .

USE AdventureWorks2012;  
GO  
SELECT City, StateProvinceID, PostalCode FROM Person.Address ORDER BY PostalCode DESC;  
GO  
DECLARE @xml_showplan nvarchar(max);  
SET @xml_showplan = (SELECT query_plan  
    FROM sys.dm_exec_query_stats AS qs   
    CROSS APPLY sys.dm_exec_sql_text(qs.sql_handle) AS st  
    CROSS APPLY sys.dm_exec_text_query_plan(qs.plan_handle, DEFAULT, DEFAULT) AS qp  
    WHERE st.text LIKE N'SELECT City, StateProvinceID, PostalCode FROM Person.Address ORDER BY PostalCode DESC;%');  
  
EXEC sp_create_plan_guide   
    @name = N'Guide1_from_XML_showplan',   
    @stmt = N'SELECT City, StateProvinceID, PostalCode FROM Person.Address ORDER BY PostalCode DESC;',   
    @type = N'SQL',  
    @module_or_batch = NULL,   
    @params = NULL,   
    @hints = @xml_showplan;  
GO