Guia de início rápido: criar um servidor e um banco de dados do Banco de Dados SQL do Azure usando o Terraform

Aplica-se a:Banco de Dados SQL do Azure

Criar um único banco de dados é a opção mais rápida e simples para criar um banco de dados no Banco de Dados SQL do Azure. Este guia de início rápido mostra como criar um único banco de dados usando o Terraform.

Terraform permite a definição, visualização e implantação de infraestrutura em nuvem. Usando Terraform, você cria arquivos de configuração usando a sintaxe HCL. A sintaxe HCL permite especificar o provedor de nuvem - como o Azure - e os elementos que compõem sua infraestrutura de nuvem. Depois de criar os arquivos de configuração, você cria um plano de execução que permite visualizar as alterações na infraestrutura antes que elas sejam implantadas. Depois de verificar as alterações, você aplica o plano de execução para implantar a infraestrutura.

Neste artigo, você aprenderá a:

Pré-requisitos

• Instalar e configurar o Terraform

Permissões

Para criar bancos de dados via Transact-SQL:CREATE DATABASE são necessárias permissões. Para criar uma base de dados, o login deve ser o login de administrador do servidor (criado quando o servidor lógico do Banco de Dados SQL do Azure foi provisionado), o administrador do Microsoft Entra do servidor, ou um membro da função de banco de dados dbmanager em master. Para obter mais informações, consulte CREATE DATABASE.

Para criar bancos de dados por meio do portal do Azure, PowerShell, CLI do Azure ou API REST: as permissões do RBAC do Azure são necessárias, especificamente a função Colaborador, Colaborador do Banco de Dados SQL ou Colaborador do SQL Server RBAC do Azure. Para obter mais informações, consulte Funções internas do RBAC do Azure.

Implementar o código Terraform

1. Crie um diretório no qual testar e executar o código Terraform de exemplo e torná-lo o diretório atual.

2. Crie um arquivo chamado providers.tf e insira o seguinte código:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

3. Crie um arquivo chamado main.tf e insira o seguinte código:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_pet" "azurerm_mssql_server_name" {
     prefix = "sql"
   }
   
   resource "random_password" "admin_password" {
     count       = var.admin_password == null ? 1 : 0
     length      = 20
     special     = true
     min_numeric = 1
     min_upper   = 1
     min_lower   = 1
     min_special = 1
   }
   
   locals {
     admin_password = try(random_password.admin_password[0].result, var.admin_password)
   }
   
   resource "azurerm_mssql_server" "server" {
     name                         = random_pet.azurerm_mssql_server_name.id
     resource_group_name          = azurerm_resource_group.rg.name
     location                     = azurerm_resource_group.rg.location
     administrator_login          = var.admin_username
     administrator_login_password = local.admin_password
     version                      = "12.0"
   }
   
   resource "azurerm_mssql_database" "db" {
     name      = var.sql_db_name
     server_id = azurerm_mssql_server.server.id
   }
   

4. Crie um arquivo chamado variables.tf e insira o seguinte código:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sql_db_name" {
     type        = string
     description = "The name of the SQL Database."
     default     = "SampleDB"
   }
   
   variable "admin_username" {
     type        = string
     description = "The administrator username of the SQL logical server."
     default     = "azureadmin"
   }
   
   variable "admin_password" {
     type        = string
     description = "The administrator password of the SQL logical server."
     sensitive   = true
     default     = null
   }
   

5. Crie um arquivo chamado outputs.tf e insira o seguinte código:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "sql_server_name" {
     value = azurerm_mssql_server.server.name
   }
   
   
   output "admin_password" {
     sensitive = true
     value     = local.admin_password
   }
   

Inicializar Terraform

Execute terraform init para inicializar a implantação do Terraform. Este comando baixa o provedor do Azure necessário para gerenciar seus recursos do Azure.

terraform init -upgrade

Pontos principais:

• O parâmetro -upgrade atualiza os plug-ins de provedor necessários para a versão mais recente que está em conformidade com as restrições de versão da configuração.

Criar um plano de execução do Terraform

Execute terraform plan para criar um plano de execução.

terraform plan -out main.tfplan

Pontos principais:

• O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
• O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

Aplicar um plano de execução do Terraform

Execute terraform apply para aplicar o plano de execução à sua infraestrutura de nuvem.

terraform apply main.tfplan

Pontos principais:

• O comando de exemplo terraform apply pressupõe que já executaste terraform plan -out main.tfplan anteriormente.
• Se você especificou um nome de arquivo diferente para o parâmetro -out, use esse mesmo nome de arquivo na chamada para terraform apply.
• Se você não usou o parâmetro -out, chame terraform apply sem nenhum parâmetro.

Verificar os resultados

Limpeza de recursos

Quando você não precisar mais dos recursos criados via Terraform, execute as seguintes etapas:

1. Execute o terraform plan e especifique o destroy flag.

   terraform plan -destroy -out main.destroy.tfplan
   

   Pontos principais:

   • O comando terraform plan cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
   • O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

2. Execute terraform apply para aplicar o plano de execução.

   terraform apply main.destroy.tfplan
   

Solucionar problemas do Terraform no Azure

Solucionar problemas comuns ao usar o Terraform no Azure

Próximo passo