Visualizações geoespaciais

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Os dados geoespaciais podem ser visualizados como parte de sua consulta usando o operador de renderização como pontos, tortas ou bolhas em um mapa.

Para obter mais informações sobre agrupamento geoespacial, consulte Agrupamento geoespacial.

Exemplos

O exemplo a seguir localiza eventos de tempestade e visualiza 100 em um mapa.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

O exemplo a seguir visualiza várias séries de pontos, onde o par [Longitude, Latitude] define cada ponto e uma terceira coluna define a série. Neste exemplo, a série é EventType.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

O exemplo a seguir visualiza uma série de pontos em um mapa. Se você tiver várias colunas no resultado, deverá especificar as colunas a serem usadas para xcolumn (Longitude), ycolumn (Latitude) e série.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

O exemplo a seguir visualiza pontos no mapa usando valores dinâmicos GeoJSON para definir os pontos.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

O exemplo a seguir mostra eventos de tempestade agregados por células S2. O gráfico agrega eventos em bolhas por localização em uma cor.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

O exemplo a seguir mostra eventos de tempestade agregados por células S2. O gráfico agrega eventos por tipo de evento em gráficos de pizza por local.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Conteúdo relacionado

• Agrupamento geoespacial
• Operador de renderização
• Análise de dados para frotas de teste automotivo (caso de uso de agrupamento geoespacial)
• Saiba mais sobre a arquitetura do Azure para processamento e análise de dados geoespaciais