Nota
O acesso a esta página requer autorização. Podes tentar iniciar sessão ou mudar de diretório.
O acesso a esta página requer autorização. Podes tentar mudar de diretório.
Applies to: ✅Microsoft Fabric✅Azure Data Explorer
O gráfico de linhas visual é o tipo mais básico de gráfico. A primeira coluna da consulta deve ser numérica e é usada como eixo x. Outras colunas numéricas são os eixos y. Os gráficos de linhas registam as alterações durante períodos de tempo curtos e longos. Quando existem alterações menores, os gráficos de linhas são mais úteis do que os gráficos de barras.
Note
This visualization can only be used in the context of the render operator.
Syntax
T|renderlinechart [with(propertyName=propertyValue [, ...] )]
Learn more about syntax conventions.
Parameters
| Name | Tipo | Required | Description |
|---|---|---|---|
| T | string |
✔️ | Nome da tabela de entrada. |
| propertyName, propertyValue | string |
Uma lista separada por vírgulas de pares de propriedades chave-valor. See supported properties. |
Supported properties
Todas as propriedades são opcionais.
| PropertyName | PropertyValue |
|---|---|
accumulate |
Se o valor de cada medida é adicionado a todas as suas antecessoras (true ou false). |
legend |
Exibir ou não uma legenda (visible ou hidden). |
series |
Lista delimitada por vírgulas de colunas cujos valores combinados por registro definem a série à qual o registro pertence. |
ymin |
O valor mínimo a ser exibido no eixo Y. |
ymax |
O valor máximo a ser exibido no eixo Y. |
title |
O título da visualização (do tipo string). |
xaxis |
Como dimensionar o eixo x (linear ou log). |
xcolumn |
Qual coluna no resultado é usada para o eixo x. |
xtitle |
O título do eixo x (do tipo string). |
yaxis |
Como dimensionar o eixo y (linear ou log). |
ycolumns |
Lista delimitada por vírgulas de colunas que consistem nos valores fornecidos por valor da coluna x. |
ysplit |
Como dividir a visualização em vários valores do eixo y. Para obter mais informações, consulte ysplit propriedade. |
ytitle |
O título do eixo y (do tipo string). |
ysplit propriedade
Esta visualização suporta a divisão em vários valores do eixo y:
ysplit |
Description |
|---|---|
none |
Um único eixo y é exibido para todos os dados da série. (Default) |
axes |
Um único gráfico é exibido com vários eixos y (um por série). |
panels |
Um gráfico é renderizado para cada ycolumn valor. Máximo de cinco painéis. |
Examples
O exemplo nesta seção mostra como usar a sintaxe para ajudá-lo a começar.
The examples in this article use publicly available tables in the help cluster, such as the
StormEventstable in the Samples database.
The examples in this article use publicly available tables, such as the
Weathertable in the Weather analytics sample gallery. Talvez seja necessário modificar o nome da tabela na consulta de exemplo para corresponder à tabela em seu espaço de trabalho.
Renderizar um gráfico de linhas
Esta consulta recupera eventos de tempestade na Virgínia, concentrando-se na hora de início e nos danos à propriedade e, em seguida, exibe essas informações em um gráfico de linhas.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart
Rotular um gráfico de linhas
Esta consulta recupera eventos de tempestade na Virgínia, concentrando-se na hora de início e nos danos à propriedade e, em seguida, exibe essas informações em um gráfico de linhas com títulos especificados para melhor clareza e apresentação.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart
with (
title="Property damage from storms in Virginia",
xtitle="Start time of storm",
ytitle="Property damage"
)
Valores-limite apresentados no eixo y
Esta consulta recupera eventos de tempestade na Virgínia, concentrando-se na hora de início e nos danos à propriedade e, em seguida, exibe essas informações em um gráfico de linhas com limites especificados do eixo y para uma melhor visualização dos dados.
StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart with (ymin=7000, ymax=300000)
Ver vários eixos y
Esta consulta recupera eventos de granizo no Texas, Nebraska e Kansas. Ele conta o número de eventos de granizo por dia para cada estado e, em seguida, exibe essas informações em um gráfico de linhas com painéis separados para cada estado.
StormEvents
| where State in ("TEXAS", "NEBRASKA", "KANSAS") and EventType == "Hail"
| summarize count() by State, bin(StartTime, 1d)
| render linechart with (ysplit=panels)
